plugins {
    id 'com.android.application'
    id 'org.jetbrains.kotlin.android'
    id 'org.jetbrains.kotlin.plugin.serialization'
}

android {
    compileSdk 34

    defaultConfig {
        applicationId "com.geode.launcher"
        minSdk 23
        targetSdk 34
        versionCode 7
        versionName "1.0.0"

        vectorDrawables {
            useSupportLibrary true
        }
        externalNativeBuild {
            cmake {
                arguments "-DUSE_TULIPHOOK:BOOL=OFF"
            }
        }

        ndkConfig.abiFilters "arm64-v8a", "armeabi-v7a"
    }

    splits {
        abi {
            enable true
            reset()

            //noinspection ChromeOsAbiSupport (not my fault)
            include "arm64-v8a", "armeabi-v7a"

            universalApk true
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        // enables a polyfill for java Instant on api levels < 26 (used for updater)
        coreLibraryDesugaringEnabled true

        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = '1.8'
    }
    buildFeatures {
        compose true
        buildConfig true
    }
    composeOptions {
        kotlinCompilerExtensionVersion compose_compiler
    }
    packagingOptions {
        resources {
            excludes += '/META-INF/{AL2.0,LGPL2.1}'
        }
    }
    externalNativeBuild {
        cmake {
            path file('src/main/cpp/CMakeLists.txt')
        }
    }
    namespace 'com.geode.launcher'
    ndkVersion '26.1.10909125'
}

dependencies {
    implementation platform('androidx.compose:compose-bom:2023.10.01')
    implementation 'androidx.core:core-ktx:1.12.0'
    implementation "androidx.compose.ui:ui"
    implementation 'androidx.compose.material3:material3'
    implementation "androidx.compose.ui:ui-tooling-preview"
    implementation 'androidx.lifecycle:lifecycle-runtime-ktx:2.7.0'
    implementation "androidx.lifecycle:lifecycle-viewmodel-compose:2.7.0"
    implementation 'androidx.activity:activity-compose:1.8.2'
    implementation 'androidx.activity:activity-ktx:1.8.2'
    implementation 'androidx.appcompat:appcompat:1.6.1'
    implementation "androidx.documentfile:documentfile:1.0.1"
    implementation "com.squareup.okio:okio:3.7.0"
    implementation "com.squareup.okhttp3:okhttp:4.12.0"
    implementation 'org.jetbrains.kotlinx:kotlinx-serialization-json:1.6.0'
    implementation 'org.jetbrains.kotlinx:kotlinx-datetime:0.5.0'
    implementation "org.jetbrains.kotlinx:kotlinx-serialization-json-okio:1.6.0"
    debugImplementation "androidx.compose.ui:ui-tooling"
    debugImplementation "androidx.compose.ui:ui-test-manifest"
    coreLibraryDesugaring "com.android.tools:desugar_jdk_libs:2.0.4"
}