feeling gradle

app/build.gradle

@@ -1,98 +0,0 @@
-plugins {
-    id 'com.android.application'
-    id 'org.jetbrains.kotlin.android'
-    id 'org.jetbrains.kotlin.plugin.serialization'
-}
-
-android {
-    compileSdk 34
-
-    defaultConfig {
-        applicationId "com.geode.launcher"
-        minSdk 23
-        targetSdk 34
-        versionCode 10
-        versionName "1.2.0"
-
-        vectorDrawables {
-            useSupportLibrary true
-        }
-        externalNativeBuild {
-            cmake {
-                arguments "-DUSE_TULIPHOOK:BOOL=OFF"
-            }
-        }
-
-        ndkConfig.abiFilters "arm64-v8a", "armeabi-v7a"
-    }
-
-    splits {
-        abi {
-            enable true
-            reset()
-
-            //noinspection ChromeOsAbiSupport (not my fault)
-            include "arm64-v8a", "armeabi-v7a"
-
-            universalApk true
-        }
-    }
-
-    buildTypes {
-        release {
-            minifyEnabled false
-            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
-        }
-    }
-    compileOptions {
-        // enables a polyfill for java Instant on api levels < 26 (used for updater)
-        coreLibraryDesugaringEnabled true
-
-        sourceCompatibility JavaVersion.VERSION_1_8
-        targetCompatibility JavaVersion.VERSION_1_8
-    }
-    kotlinOptions {
-        jvmTarget = '1.8'
-    }
-    buildFeatures {
-        compose true
-        buildConfig true
-    }
-    composeOptions {
-        kotlinCompilerExtensionVersion compose_compiler
-    }
-    packagingOptions {
-        resources {
-            excludes += '/META-INF/{AL2.0,LGPL2.1}'
-        }
-    }
-    externalNativeBuild {
-        cmake {
-            path file('src/main/cpp/CMakeLists.txt')
-        }
-    }
-    namespace 'com.geode.launcher'
-    ndkVersion '26.1.10909125'
-}
-
-dependencies {
-    implementation platform('androidx.compose:compose-bom:2023.10.01')
-    implementation 'androidx.core:core-ktx:1.12.0'
-    implementation "androidx.compose.ui:ui"
-    implementation 'androidx.compose.material3:material3'
-    implementation "androidx.compose.ui:ui-tooling-preview"
-    implementation 'androidx.lifecycle:lifecycle-runtime-ktx:2.7.0'
-    implementation "androidx.lifecycle:lifecycle-viewmodel-compose:2.7.0"
-    implementation 'androidx.activity:activity-compose:1.8.2'
-    implementation 'androidx.activity:activity-ktx:1.8.2'
-    implementation 'androidx.appcompat:appcompat:1.6.1'
-    implementation "androidx.documentfile:documentfile:1.0.1"
-    implementation "com.squareup.okio:okio:3.7.0"
-    implementation "com.squareup.okhttp3:okhttp:4.12.0"
-    implementation 'org.jetbrains.kotlinx:kotlinx-serialization-json:1.6.0'
-    implementation 'org.jetbrains.kotlinx:kotlinx-datetime:0.5.0'
-    implementation "org.jetbrains.kotlinx:kotlinx-serialization-json-okio:1.6.0"
-    debugImplementation "androidx.compose.ui:ui-tooling"
-    debugImplementation "androidx.compose.ui:ui-test-manifest"
-    coreLibraryDesugaring "com.android.tools:desugar_jdk_libs:2.0.4"
-}

app/build.gradle.kts

@@ -0,0 +1,101 @@
+val composeCompiler: String by rootProject.extra
+val composeBOM: String by rootProject.extra
+
+plugins {
+    id("com.android.application")
+    id("org.jetbrains.kotlin.android")
+    id("org.jetbrains.kotlin.plugin.serialization")
+}
+
+android {
+    compileSdk = 34
+
+    defaultConfig {
+        applicationId = "com.geode.launcher"
+        minSdk = 23
+        targetSdk = 34
+        versionCode = 10
+        versionName = "1.2.0"
+
+        vectorDrawables {
+            useSupportLibrary = true
+        }
+        externalNativeBuild {
+            cmake {
+                arguments("-DUSE_TULIPHOOK:BOOL=OFF")
+            }
+        }
+
+        ndk.abiFilters += listOf("arm64-v8a", "armeabi-v7a")
+    }
+
+    splits {
+        abi {
+            isEnable = true
+            reset()
+
+            //noinspection ChromeOsAbiSupport (not my fault)
+            include("arm64-v8a", "armeabi-v7a")
+
+            isUniversalApk = true
+        }
+    }
+
+    buildTypes {
+        release {
+            isMinifyEnabled = false
+            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
+        }
+    }
+    compileOptions {
+        // enables a polyfill for java Instant on api levels < 26 (used for updater)
+        isCoreLibraryDesugaringEnabled = true
+
+        sourceCompatibility = JavaVersion.VERSION_1_8
+        targetCompatibility = JavaVersion.VERSION_1_8
+    }
+    kotlinOptions {
+        jvmTarget = "1.8"
+    }
+    buildFeatures {
+        compose = true
+        buildConfig = true
+    }
+    composeOptions {
+        kotlinCompilerExtensionVersion = composeCompiler
+    }
+    packaging {
+        resources {
+            excludes += "/META-INF/{AL2.0,LGPL2.1}"
+        }
+    }
+    externalNativeBuild {
+        cmake {
+            path = file("src/main/cpp/CMakeLists.txt")
+        }
+    }
+    namespace = "com.geode.launcher"
+    ndkVersion = "26.1.10909125"
+}
+
+dependencies {
+    implementation (platform("androidx.compose:compose-bom:$composeBOM"))
+    implementation ("androidx.core:core-ktx:1.12.0")
+    implementation ("androidx.compose.ui:ui")
+    implementation ("androidx.compose.material3:material3")
+    implementation ("androidx.compose.ui:ui-tooling-preview")
+    implementation ("androidx.lifecycle:lifecycle-runtime-ktx:2.7.0")
+    implementation ("androidx.lifecycle:lifecycle-viewmodel-compose:2.7.0")
+    implementation ("androidx.activity:activity-compose:1.8.2")
+    implementation ("androidx.activity:activity-ktx:1.8.2")
+    implementation ("androidx.appcompat:appcompat:1.6.1")
+    implementation ("androidx.documentfile:documentfile:1.0.1")
+    implementation ("com.squareup.okio:okio:3.7.0")
+    implementation ("com.squareup.okhttp3:okhttp:4.12.0")
+    implementation ("org.jetbrains.kotlinx:kotlinx-serialization-json:1.6.0")
+    implementation ("org.jetbrains.kotlinx:kotlinx-datetime:0.5.0")
+    implementation ("org.jetbrains.kotlinx:kotlinx-serialization-json-okio:1.6.0")
+    debugImplementation ("androidx.compose.ui:ui-tooling")
+    debugImplementation ("androidx.compose.ui:ui-test-manifest")
+    coreLibraryDesugaring ("com.android.tools:desugar_jdk_libs:2.0.4")
+}

build.gradle

@@ -1,17 +0,0 @@
-buildscript {
-    ext {
-        compose_compiler = '1.5.8'
-    }
-}
-
-// Top-level build file where you can add configuration options common to all sub-projects/modules.
-plugins {
-    id 'com.android.application' version '8.2.2' apply false
-    id 'com.android.library' version '8.2.2' apply false
-    id 'org.jetbrains.kotlin.android' version '1.9.22' apply false
-    id 'org.jetbrains.kotlin.plugin.serialization' version '1.9.22' apply false
-}
-
-tasks.register('clean', Delete) {
-    delete rootProject.layout.buildDirectory
-}

build.gradle.kts

@@ -0,0 +1,16 @@
+buildscript {
+    val composeBOM by extra("2023.10.01")
+    val composeCompiler by extra("1.5.8")
+}
+
+// Top-level build file where you can add configuration options common to all sub-projects/modules.
+plugins {
+    id("com.android.application") version "8.2.2" apply false
+    id("com.android.library") version "8.2.2" apply false
+    id("org.jetbrains.kotlin.android") version "1.9.22" apply false
+    id("org.jetbrains.kotlin.plugin.serialization") version "1.9.22" apply false
+}
+
+tasks.register<Delete>("clean") {
+    delete(rootProject.layout.buildDirectory)
+}

gradle/wrapper/gradle-wrapper.properties

@@ -1,6 +1,6 @@
 distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
-distributionUrl=https\://services.gradle.org/distributions/gradle-8.3-bin.zip
+distributionUrl=https\://services.gradle.org/distributions/gradle-8.5-bin.zip
 networkTimeout=10000
 validateDistributionUrl=true
 zipStoreBase=GRADLE_USER_HOME

gradlew

@@ -145,7 +145,7 @@ if ! "$cygwin" && ! "$darwin" && ! "$nonstop" ; then
     case $MAX_FD in #(
       max*)
         # In POSIX sh, ulimit -H is undefined. That's why the result is checked to see if it worked.
-        # shellcheck disable=SC3045
+        # shellcheck disable=SC2039,SC3045
         MAX_FD=$( ulimit -H -n ) ||
             warn "Could not query maximum file descriptor limit"
     esac
@@ -153,7 +153,7 @@ if ! "$cygwin" && ! "$darwin" && ! "$nonstop" ; then
       '' | soft) :;; #(
       *)
         # In POSIX sh, ulimit -n is undefined. That's why the result is checked to see if it worked.
-        # shellcheck disable=SC3045
+        # shellcheck disable=SC2039,SC3045
         ulimit -n "$MAX_FD" ||
             warn "Could not set maximum file descriptor limit to $MAX_FD"
     esac
@@ -202,11 +202,11 @@ fi
 # Add default JVM options here. You can also use JAVA_OPTS and GRADLE_OPTS to pass JVM options to this script.
 DEFAULT_JVM_OPTS='"-Xmx64m" "-Xms64m"'
 
-# Collect all arguments for the java command;
-#   * $DEFAULT_JVM_OPTS, $JAVA_OPTS, and $GRADLE_OPTS can contain fragments of
-#     shell script including quotes and variable substitutions, so put them in
-#     double quotes to make sure that they get re-expanded; and
-#   * put everything else in single quotes, so that it's not re-expanded.
+# Collect all arguments for the java command:
+#   * DEFAULT_JVM_OPTS, JAVA_OPTS, JAVA_OPTS, and optsEnvironmentVar are not allowed to contain shell fragments,
+#     and any embedded shellness will be escaped.
+#   * For example: A user cannot expect ${Hostname} to be expanded, as it is an environment variable and will be
+#     treated as '${Hostname}' itself on the command line.
 
 set -- \
         "-Dorg.gradle.appname=$APP_BASE_NAME" \

settings.gradle.kts

@@ -5,6 +5,8 @@ pluginManagement {
         mavenCentral()
     }
 }
+
+@Suppress("UnstableApiUsage")
 dependencyResolutionManagement {
     repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
     repositories {
@@ -12,5 +14,6 @@ dependencyResolutionManagement {
         mavenCentral()
     }
 }
+
 rootProject.name = "launcher"
-include ':app'
+include(":app")