import org.sayandev.plugin.StickyNoteModules

plugins {
    java
    id("xyz.jpenilla.run-paper") version "3.0.2"
    id("de.eldoria.plugin-yml.bukkit") version "0.8.0"
    id("org.sayandev.stickynote.project")
}

val slug = rootProject.name.lowercase()
group = "xyz.lncvrt"
version = "1.0.0"

stickynote {
    modules(StickyNoteModules.BUKKIT)
}

repositories {
    mavenCentral()
    mavenLocal()
    
    maven("https://repo.sayandev.org/snapshots")
    maven("https://repo.sayandev.org/releases")
    maven("https://repo.sayandev.org/private")
    maven("https://repo.extendedclip.com/releases/")
    maven("https://jitpack.io")
    maven("https://ci.frostcast.net/plugin/repository/everything")
}

dependencies {
    compileOnly("io.papermc.paper:paper-api:1.21.10-R0.1-SNAPSHOT")
    compileOnly("me.clip:placeholderapi:2.11.7")
    compileOnly("com.github.booksaw:BetterTeams:4.15.2")
    compileOnly("me.confuser.banmanager:BanManagerCommon:7.9.0")
    implementation("com.googlecode.json-simple:json-simple:1.1.1")
}

tasks {
    jar {
        manifest {
            attributes["paperweight-mappings-namespace"] = "mojang"
        }
    }

    shadowJar {
        archiveFileName.set("${rootProject.name}-${version}.jar")
        archiveClassifier.set(null as String?)
        destinationDirectory.set(file(rootProject.projectDir.path + "/bin"))
        manifest {
            attributes["paperweight-mappings-namespace"] = "mojang"
        }
    }
    
    runServer {
        minecraftVersion("1.21.10")
        
        jvmArgs()
    }
    
    compileJava {
        options.encoding = Charsets.UTF_8.name()
    }
    
    configurations {
        create("compileOnlyApiResolved") {
            isCanBeResolved = true
            extendsFrom(configurations.getByName("compileOnlyApi"))
        }
    }

    build {
        dependsOn(shadowJar)
    }
    
    processResources {
        filesMatching(listOf("**plugin.yml", "**plugin.json")) {
            expand(
                "version" to project.version as String,
                "slug" to slug,
                "name" to rootProject.name
            )
        }
    }
}
    
bukkit {
    main = "$group.${slug}.${rootProject.name}Plugin"
    version = rootProject.version.toString()
    website = "lncvrt.xyz"
    apiVersion = "1.21.10"
    depend = listOf("PlaceholderAPI", "BetterTeams", "BanManager")
    authors = listOf("Lncvrt")
    prefix = rootProject.name
}
    
java {
    disableAutoTargetJvm()
    toolchain.languageVersion.set(JavaLanguageVersion.of(21))
}